#!/bin/tcsh -f
#
# This shell script installs font bitmaps (./*.tfm, ./*pk)
# which have been created with mk_xxxx.
#
# Usage: FontInstall METAFONT-MODE SUPPLIER TYPEFACE
#
# VK 21 Jul 94, 1 Jan 95, 7 Jan 95, 8 Apr 95; 29 Sep 95; 08 Apr 96
#

if ($#argv < 3) then
  echo '\
Usage: '"$0:t"' METAFONT-MODE SUPPLIER TYPEFACE [PATTERN]\
  Copies ./*pk to $FONTS/pk/METAFONT-MODE/SUPPLIER/TYPEFACE/\
  Copies ./*.tfm to $FONTS/tfm/SUPPLIER/TYPEFACE/\
  (METAFONT-MODE: e.g. cx, ljfour)\
  (SUPPLIER: e.g. public, ams; TYPEFACE: e.g. cm, latex)\
  (PATTERN: name pattern, e.g. "eu*" for ams euler fonts. Must be quoted!\!)\
  $FONTS defaults to $TEXMF/fonts/\
  $TEXMF must be set\
'
  exit 1
endif

if ( ! $?TEXMF ) then
  echo '$TEXMF is not set. Please set and re-run.'
  exit 5
endif

if ( ! $?FONTS ) then
  echo '$FONTS is not set - set to '"$TEXMF/fonts"
  setenv FONTS $TEXMF/fonts
endif

set mfmode="$1"
set supplier="$2"
set typeface="$3"
set pattern="$4"
if ( "$pattern" == "" ) set pattern='*'


set dirname="$FONTS/pk/$mfmode/$supplier/$typeface"
if ( ! -e $dirname ) then
  echo "Creating $dirname"
  mkdir -p $dirname
endif
echo "Copying ./*pk files to $dirname"
cp -p {$pattern}pk $dirname

set dirname="$FONTS/tfm/$supplier/$typeface"
if ( ! -e $dirname ) then
  echo "Creating $dirname"
  mkdir -p $dirname
endif
echo "Copying ./*.tfm files to $dirname"
cp -p {$pattern}.tfm $dirname