// Gong sound
IfCleanedUp
  tmpargument = 1
  PlayFullSound


// Talk to player
IfBored
  tmpx = rand & 1
  tmpargument = tmpx + 7
  SendMessageNear
  tmpargument = tmpx + 6
  PlaySound
  tmpargument = ACTIONMC
  DoAction

IfTooMuchBaggage
  tmpargument = 6
  SendMessageNear
  tmpargument = 9
  PlaySound


// Heal sound
IfUsed
  tmpargument = 0
  PlayFullSound
  tmpargument = 25
  SetReloadTime



// Handle death
IfKilled
  // Sound
  tmpargument = 8
  PlaySound

  // Message
  tmpargument = 3
  IfArmorIs
    tmpargument = MESSAGECOSTUME
  Else
    tmpargument = MESSAGEDEATH
  IfTargetIsOnSameTeam
    tmpargument = MESSAGEFRAG
    IfTargetIsSelf
      tmpargument = MESSAGEACCIDENT
  SendMessage


  // Misc.
  tmpargument = 1+selflevel*selflevel*100		//The money loss formula
  DropMoney
  DropKeys
  tmpargument = 45
  SetBumpHeight

  tmpx = 9999			//Special healer power
  IfXIsEqualToY
    SetTargetToSelf
    RespawnTarget
    tmpargument = 9
    SendMessageNear

//------------------------------------------------------------------------------
//Invoke special power if enough xp gained
IfStateIs0
  SetTargetToSelf
  tmpx = targetexp
  tmpy = 9998
  IfXIsMoreThanY
    SetOwnerToTarget
    EnchantTarget 	//Give the special bonus
    tmpargument = 1
    SetState
  Else
    tmpargument = 0
    SetState
    UndoEnchant
Else
  tmpargument = 4	//Spawn some fancy sparklies
  tmpx = selfx
  tmpy = selfy
  tmpdistance = selfz
  SpawnExactParticle


// Just because...
IfLeaderKilled
  BecomeLeader


// Yell at friends
IfAttacked
  SetTargetToWhoeverAttacked
  IfTargetIsOnSameTeam
    tmpargument = MESSAGEOUCH
    SendMessage
    tmpargument = 4
    PlaySound
  Else
    tmpargument = rand & 1 + 2
    PlaySound


// All done
End
